tem_evalAdd_forElement Subroutine

public recursive subroutine tem_evalAdd_forElement(fun, varSys, elempos, time, tree, nElems, nDofs, res)

Evaluate the function pointers of the dependent variables, and then calculate the addition or arbinary number of input variables with all input variables have same nComponents. ( scalar or vector ) In lua file, first define new variable with varType operation kind as "addition" and provide two dependent variable via input_varname. If input_varname variable is not part of predefined solver variables then add also that variable via variable table for example spacetime function variable.

\verbatim -- in lua file, one can define as following: variable = {{ name = 'dens_reference', ncomponents = 1, vartype = "st_fun", st_fun = luaFun }, { name = 'dens_difference', ncomponents = 1, vartype = "operation", operation = {kind='addition', input_varname={density, dens_reference}} } ... } \endverbatim

The interface has to comply to the abstract interface tem_varSys_module#tem_varSys_proc_element.

Arguments

Type IntentOptional Attributes Name
class(tem_varSys_op_type), intent(in) :: fun

Description of the method to obtain the variables, here some preset values might be stored, like the space time function to use or the required variables.
type(tem_varSys_type), intent(in) :: varSys

The variable system to obtain the variable from.
integer, intent(in) :: elempos(:)

Position of the TreeID of the element to get the variable for in the global treeID list.
type(tem_time_type), intent(in) :: time

Point in time at which to evaluate the variable.
type(treelmesh_type), intent(in) :: tree

global treelm mesh info
integer, intent(in) :: nElems

Number of values to obtain for this variable (vectorized access).
integer, intent(in) :: nDofs

Number of degrees of freedom within an element.
real(kind=rk), intent(out) :: res(:)

Resulting values for the requested variable.

Linearized array dimension: (n requested entries) x (nComponents of this variable) x (nDegrees of freedom) Access: (iElem-1)fun%nComponentsnDofs + (iDof-1)*fun%nComponents + iComp

Source Code

  recursive subroutine tem_evalAdd_forElement( fun, varsys, elempos, time, &
    &                                          tree, nElems, nDofs, res    )
    ! ---------------------------------------------------------------------- !
    !> Description of the method to obtain the variables, here some preset
    !! values might be stored, like the space time function to use or the
    !! required variables.
    class(tem_varSys_op_type), intent(in) :: fun

    !> The variable system to obtain the variable from.
    type(tem_varSys_type), intent(in) :: varSys

    !> Position of the TreeID of the element to get the variable for in the
    !! global treeID list.
    integer, intent(in) :: elempos(:)

    !> Point in time at which to evaluate the variable.
    type(tem_time_type), intent(in)  :: time

    !> global treelm mesh info
    type(treelmesh_type), intent(in) :: tree

    !> Number of values to obtain for this variable (vectorized access).
    integer, intent(in) :: nElems

    !> Number of degrees of freedom within an element.
    integer, intent(in) :: nDofs

    !> Resulting values for the requested variable.
    !!
    !! Linearized array dimension:
    !! (n requested entries) x (nComponents of this variable)
    !! x (nDegrees of freedom)
    !! Access: (iElem-1)*fun%nComponents*nDofs +
    !!         (iDof-1)*fun%nComponents + iComp
    real(kind=rk), intent(out) :: res(:)
    ! ---------------------------------------------------------------------- !
    integer :: iDep, posDepVar
    real(kind=rk), allocatable :: input_varRes(:)
    integer :: nTotal
    ! ---------------------------------------------------------------------- !

    nTotal = nElems*nDofs*fun%nComponents
    allocate(input_varRes(nTotal))

    res = 0.0_rk
    do iDep = 1, fun%nInputs
      ! get position of dependent var in varSys
      posDepVar = fun%input_varPos(iDep)

      ! derive dependent variable
      call varSys%method%val(posDepVar)%get_element(               &
        &                                   varSys  = varSys,      &
        &                                   elemPos = elemPos,     &
        &                                   time    = time,        &
        &                                   tree    = tree,        &
        &                                   nElems  = nElems,      &
        &                                   nDofs   = nDofs,       &
        &                                   res     = input_varRes )

      res(:nTotal) = res(:nTotal) + input_varRes
    end do

    deallocate(input_varRes)

  end subroutine tem_evalAdd_forElement