tem_divideVecByScal_fromIndex Subroutine

public recursive subroutine tem_divideVecByScal_fromIndex(fun, varSys, time, iLevel, idx, idxLen, nVals, res)

Same as divideVecByScal_fromElement except it divide values from points via indices which are setup before

The interface has to comply to the abstract interface tem_varSys_module#tem_varSys_proc_getvalofindex.

TODO make it working for idxLen and contiguous access of index array

Arguments

Type IntentOptional Attributes Name
class(tem_varSys_op_type), intent(in) :: fun

Description of the method to obtain the variables, here some preset values might be stored, like the space time function to use or the required variables.
type(tem_varSys_type), intent(in) :: varSys

The variable system to obtain the variable from.
type(tem_time_type), intent(in) :: time

Point in time at which to evaluate the variable.
integer, intent(in) :: iLevel

Level on which values are requested
integer, intent(in) :: idx(:)

Index of points in the growing array and variable val array to return. Size: nVals
integer, intent(in), optional :: idxLen(:)

With idx as start index in contiguous memory, idxLength defines length of each contiguous memory Size: nVals
integer, intent(in) :: nVals

Number of values to obtain for this variable (vectorized access).
real(kind=rk), intent(out) :: res(:)

Resulting values for the requested variable.

Dimension: n requested entries x nComponents of this variable Access: (iElem-1)*fun%nComponents + iComp

Calls

proc~~tem_dividevecbyscal_fromindex~~CallsGraph proc~tem_dividevecbyscal_fromindex tem_divideVecByScal_fromIndex proc~tem_varsys_check_inargs tem_varSys_check_inArgs proc~tem_dividevecbyscal_fromindex->proc~tem_varsys_check_inargs

Source Code

  recursive subroutine tem_divideVecByScal_fromIndex( fun, varSys, time,   &
    &                                                 iLevel, idx, idxLen, &
    &                                                 nVals, res           )
    !--------------------------------------------------------------------------!
    !> Description of the method to obtain the variables, here some preset
    !! values might be stored, like the space time function to use or the
    !! required variables.
    class(tem_varSys_op_type), intent(in) :: fun

    !> The variable system to obtain the variable from.
    type(tem_varSys_type), intent(in) :: varSys

    !> Point in time at which to evaluate the variable.
    type(tem_time_type), intent(in) :: time

    !> Level on which values are requested
    integer, intent(in) :: iLevel

    !> Index of points in the growing array and variable val array to
    !! return.
    !! Size: nVals
    integer, intent(in) :: idx(:)

    !> With idx as start index in contiguous memory,
    !! idxLength defines length of each contiguous memory
    !! Size: nVals
    integer, optional, intent(in) :: idxLen(:)

    !> Number of values to obtain for this variable (vectorized access).
    integer, intent(in) :: nVals

    !> Resulting values for the requested variable.
    !!
    !! Dimension: n requested entries x nComponents of this variable
    !! Access: (iElem-1)*fun%nComponents + iComp
    real(kind=rk), intent(out) :: res(:)
    !--------------------------------------------------------------------------!
    type(tem_varSys_op_data_type), pointer :: opData
    real(kind=rk) :: divisor(nVals)
    real(kind=rk) :: dividend(nVals*fun%nComponents)
    integer :: iComp, iVal
    !--------------------------------------------------------------------------!
    write(logUnit(4),*) 'Get the values of indices for derived variable',&
      &                  'by divideVecByScal ',                          &
      &                  trim(varSys%varname%val(fun%myPos))
    call C_F_POINTER( fun%method_Data, opData )

    ! get the nodal values for the 2 inputs
    !>TODO make it working for idxLen and contiguous access of index array
    call tem_varSys_check_inArgs( fun, varSys, time, iLevel, idx, idxLen, &
      &    nVals, label = 'tem_divideVecByScal_fromIndex'            )

    call varSys%method%val(fun%input_varPos(1))%get_valOfIndex( &
      & varSys  = varSys,                                       &
      & time    = time,                                         &
      & iLevel  = iLevel,                                       &
      & idx     = opData%input_pntIndex(1)                      &
      &           %indexLvl(iLevel)%val( idx(:) ),              &
      & nVals   = nVals,                                        &
      & res     = dividend                                      )

    call varSys%method%val(fun%input_varPos(2))%get_valOfIndex( &
      & varSys  = varSys,                                       &
      & time    = time,                                         &
      & iLevel  = iLevel,                                       &
      & idx     = opData%input_pntIndex(2)                      &
      &           %indexLvl(iLevel)%val( idx(:) ),              &
      & nVals   = nVals,                                        &
      & res     = divisor                                       )

    do iVal = 1, nVals
      do iComp = 1, fun%nComponents
        res((iVal-1)*fun%nComponents + iComp) =                      &
          & dividend((iVal-1)*fun%nComponents + iComp) / divisor(iVal)
      end do
    end do
  end subroutine tem_divideVecByScal_fromIndex