evalLogicalLessOrEqual_fromIndex Subroutine

  subroutine evalLogicalLessOrEqual_fromIndex( fun, varSys, time, iLevel,    &
      &                                        idx, idxLen, nVals, res )
    !--------------------------------------------------------------------------!
    !> Description of the method to obtain the variables, here some preset
    !! values might be stored, like the space time function to use or the
    !! required variables.
    class(tem_varSys_op_type), intent(in) :: fun

    !> The variable system to obtain the variable from.
    type(tem_varSys_type), intent(in) :: varSys

    !> Point in time at which to evaluate the variable.
    type(tem_time_type), intent(in) :: time

    !> Level on which values are requested
    integer, intent(in) :: iLevel

    !> Index of points in the growing array and variable val array to
    !! return.
    !! Size: nVals
    integer, intent(in) :: idx(:)

    !> With idx as start index in contiguous memory,
    !! idxLength defines length of each contiguous memory
    !! Size: nVals
    integer, optional, intent(in) :: idxLen(:)

    !> Number of values to obtain for this variable (vectorized access).
    integer, intent(in) :: nVals

    !> Resulting values for the requested variable.
    !!
    !! Dimension: n requested entries x nComponents of this variable
    !! Access: (iElem-1)*fun%nComponents + iComp
    real(kind=rk), intent(out) :: res(:)
    !--------------------------------------------------------------------------!
    integer :: iDep, posDepVar
    ! first dimension:nElems,
    ! second dimension:size of difference variable in input_varname
    real(kind=rk), allocatable :: input_varRes(:,:)
    type(tem_varSys_op_data_type), pointer :: fPtr
    !--------------------------------------------------------------------------!

    call C_F_POINTER( fun%method_Data, fPtr )


    ! nInputs must be two
    allocate(input_varRes(nVals*fun%nComponents, fun%nInputs))

    do iDep = 1, fun%nInputs
      ! get position of dependent var in varSys
      posDepVar = fun%input_varPos(iDep)

      ! derive dependent variable for indices
      !rent derive dependent variable
      call varSys%method%val(posDepVar)%get_valOfIndex( &
        & varSys  = varSys,                             &
        & time    = time,                               &
        & iLevel  = iLevel,                             &
        & idx     = fPtr%input_pntIndex(iDep)           &
        &           %indexLvl(iLevel)%val( idx(:) ),    &
        & idxLen  = idxLen,                             &
        & nVals   = nVals,                              &
        & res     = input_varRes(:,iDep)                )
    end do

    res = logicalToRealArray(                             &
      & value = input_varRes(:, 1) <= input_varRes(:, 2), &
      & n     = nVals                                     )

    deallocate(input_varRes)

  end subroutine evalLogicalLessOrEqual_fromIndex